Modelica® Language Specification version 3.5

Chapter 3 Operators and Expressions

(February 18, 2021)

The lexical units are combined to form even larger building blocks such as expressions according to the rules given by the expression part of the Modelica grammar in appendix A. For example, they can be built from operators, function references, components, or component references (referring to components) and literals. Each expression has a type and a variability.

This chapter describes the evaluation rules for expressions, the concept of expression variability, built-in mathematical operators and functions, and the built-in special Modelica operators with function syntax.

Expressions can contain variables and constants, which have types, predefined or user defined. The predefined built-in types of Modelica are Real, Integer, Boolean, String, and enumeration types which are presented in more detail in section 4.8.

3.1 Expressions

Modelica equations, assignments and declaration equations contain expressions.

Expressions can contain basic operations, +, -, *, /, ^, etc. with normal precedence as defined in the Table in section 3.2 and the grammar in appendix A. The semantics of the operations is defined for both scalar and array arguments in section 10.6.

It is also possible to define functions and call them in a normal fashion. The function call syntax for both positional and named arguments is described in section 12.4.1 and for vectorized calls in section 12.4.4. The built-in array functions are given in section 10.1.1 and other built-in operators in section 3.7.

3.2 Operator Precedence and Associativity

Operator precedence determines the order of evaluation of operators in an expression. An operator with higher precedence is evaluated before an operator with lower precedence in the same expression.

The following table presents all the expression operators in order of precedence.

Table 3.1: Operators in order of precedence from highest to lowest, as derived from the Modelica grammar in appendix A. All operators are binary except the postfix operators and those shown as unary together with expr, the conditional operator, the array construction operator \{ \} and concatenation operator [ ], and the array range constructor which is either binary or ternary. Operators with the same precedence occur at the same table row.
Operator group Operator syntax Examples
Postfix array index operator [] arr[index]
Postfix access operator . a.b
Postfix function call 𝑓𝑢𝑛𝑐𝑁𝑎𝑚𝑒(𝑓𝑢𝑛𝑐𝑡𝑖𝑜𝑛𝐴𝑟𝑔𝑢𝑚𝑒𝑛𝑡𝑠) sin(4.36)
Array construction {𝑒𝑥𝑝𝑟𝑒𝑠𝑠𝑖𝑜𝑛𝑠} {2, 3}
Horizontal concatenation [𝑒𝑥𝑝𝑟𝑒𝑠𝑠𝑖𝑜𝑛𝑠] [5, 6]
Vertical concatenation [𝑒𝑥𝑝𝑟𝑒𝑠𝑠𝑖𝑜𝑛𝑠; 𝑒𝑥𝑝𝑟𝑒𝑠𝑠𝑖𝑜𝑛𝑠] [2, 3; 7, 8]
Exponentiation  ^ 2 ^ 3
Multiplicative * / 2 * 3, 2 / 3
Elementwise multiplicative .* ./ [1, 2; 3, 4] .* [2, 3; 5, 6]
Additive + - 1 + 2
Additive unary +𝑒𝑥𝑝𝑟 -𝑒𝑥𝑝𝑟 -0.5
Array elementwise additive .+ .- [1, 2; 3, 4] .+ [2, 3; 5, 6]
Relational < <= > >= == <> a < b, a <= b, a > b, …
Unary negation not 𝑒𝑥𝑝𝑟 not b1
Logical and and b1 and b2
Logical or or b1 or b2
Array range 𝑒𝑥𝑝𝑟 : 𝑒𝑥𝑝𝑟 1 : 5
𝑒𝑥𝑝𝑟 : 𝑒𝑥𝑝𝑟 : 𝑒𝑥𝑝𝑟 start : step : stop
Conditional if 𝑒𝑥𝑝𝑟 then 𝑒𝑥𝑝𝑟 else 𝑒𝑥𝑝𝑟 if b then 3 else x
Named argument 𝑖𝑑𝑒𝑛𝑡 = 𝑒𝑥𝑝𝑟 x = 2.26

The conditional operator may also include elseif-clauses. Equality = and assignment := are not expression operators since they are allowed only in equations and in assignment statements respectively. All binary expression operators are left associative, except exponentiation which is non-associative. The array range operator is non-associative.

[The unary minus and plus in Modelica is slightly different than in Mathematica11 1 Mathematica is a registered trademark of Wolfram Research Inc. and in MATLAB22 2 MATLAB is a registered trademark of MathWorks Inc., since the following expressions are illegal (whereas in Mathematica and in MATLAB these are valid expressions):

2*-2  // = -4 in Mathematica/MATLAB; is illegal in Modelica
--2   // = 2 in Mathematica/MATLAB; is illegal in Modelica
++2   // = 2 in Mathematica/MATLAB; is illegal in Modelica
2--2  // = 4 in Mathematica/MATLAB; is illegal in Modelica

Non-associative exponentiation and array range operator:

x^y^z         // Not legal, use parenthesis to make it clear
a:b:c:d:e:f:g // Not legal, and scalar arguments gives no legal interpretation.

]

3.3 Evaluation Order

A tool is free to solve equations, reorder expressions and to not evaluate expressions if their values do not influence the result (e.g. short-circuit evaluation of Boolean expressions). If-statements and if-expressions guarantee that their clauses are only evaluated if the appropriate condition is true, but relational operators generating state or time events will during continuous integration have the value from the most recent event.

If a numeric operation overflows the result is undefined. For literals it is recommended to automatically convert the number to another type with greater precision.

3.3.1 Example: Guarding Expressions Against Incorrect Evaluation

[Example: If one wants to guard an expression against incorrect evaluation, it should be guarded by an if:

  Boolean v[n];
  Boolean b;
  Integer I;
equation
  b=(I>=1 and I<=n) and v[I]; // Invalid
  b=if (I>=1 and I<=n) then v[I] else false; // Correct

To guard square against square root of negative number use noEvent:

der(h)=if h>0 then -c*sqrt(h) else 0; // Incorrect
der(h)=if noEvent(h>0) then -c*sqrt(h) else 0; // Correct

]

3.4 Arithmetic Operators

Modelica supports five binary arithmetic operators that operate on any numerical type:

Operator Description
^ Exponentiation
* Multiplication
/ Division
+ Addition
- Subtraction

Some of these operators can also be applied to a combination of a scalar type and an array type, see section 10.6.

The syntax of these operators is defined by the following rules from the Modelica grammar:

arithmetic-expression :
   [ add-operator ] term { add-operator term }
add-operator :
   "+" | "-"
term :
   factor { mul-operator factor }
mul-operator :
   "*" | "/"
factor :
   primary [ "^" primary ]

3.5 Equality, Relational, and Logical Operators

Modelica supports the standard set of relational and logical operators, all of which produce the standard boolean values true or false:

Operator Description
> Greater than
>= Greater than or equal
< Less than
<= Less than or equal to
== Equality within expressions
<> Inequality

A single equals sign = is never used in relational expressions, only in equations (chapter 8, section 10.6.1) and in function calls using named parameter passing (section 12.4.1).

The following logical operators are defined:

Operator Description
not Logical negation (unary operator)
and Logical and (conjunction)
or Logical or (disjunction)

The grammar rules define the syntax of the relational and logical operators.

logical-expression :
   logical-term { or logical-term }
logical-term :
   logical-factor { and logical-factor }
logical-factor :
   [ not ] relation
relation :
   arithmetic-expression [ relational-operator arithmetic-expression ]
relational-operator :
   "<" | "<=" | ">" | ">=" | "==" | "<>"

The following holds for relational operators:

  • Relational operators <, <=,>, >=, ==, <>, are only defined for scalar operands of simple types. The result is Boolean and is true or false if the relation is fulfilled or not, respectively.

  • For operands of type String, str1 𝑜𝑝 str2 is for each relational operator, 𝑜𝑝, defined in terms of the C function strcmp as strcmp(str1, str2) 𝑜𝑝 0.

  • For operands of type Boolean, false < true.

  • For operands of enumeration types, the order is given by the order of declaration of the enumeration literals.

  • In relations of the form v1 == v2 or v1 <> v2, v1 or v2 shall, unless used in a function, not be a subtype of Real.

    [The reason for this rule is that relations with Real arguments are transformed to state events (see Events, section 8.5) and this transformation becomes unnecessarily complicated for the == and <> relational operators (e.g. two crossing functions instead of one crossing function needed, epsilon strategy needed even at event instants). Furthermore, testing on equality of Real variables is questionable on machines where the number length in registers is different to number length in main memory.]

  • Relational operators can generate events, see section 3.8.3.

3.6 Miscellaneous Operators and Variables

Modelica also contains a few built-in operators which are not standard arithmetic, relational, or logical operators. These are described below, including time, which is a built-in variable, not an operator.

3.6.1 String Concatenation

Concatenation of strings (see the Modelica grammar) is denoted by the + operator in Modelica.

[Example: "a" + "b" becomes "ab".]

3.6.2 Array Constructor Operator

The array constructor operator {  } is described in section 10.4.

3.6.3 Array Concatenation Operator

The array concatenation operator [  ] is described in section 10.4.2.

3.6.4 Array Range Operator

The array range constructor operator : is described in section 10.4.3.

3.6.5 If-Expressions

An expression

if expression1 then expression2 else expression3

is one example of if-expression. First expression1, which must be Boolean expression, is evaluated. If expression1 is true expression2 is evaluated and is the value of the if-expression, else expression3 is evaluated and is the value of the if-expression. The two expressions, expression2 and expression3, must be type compatible expressions (section 6.7) giving the type of the if-expression. If-expressions with elseif are defined by replacing elseif by else if. For short-circuit evaluation see section 3.3.

[elseif in expressions has been added to the Modelica language for symmetry with if-clauses.]

[Example:

Integer i;
Integer sign_of_i1=if i<0 then -1 elseif i==0 then 0 else 1;
Integer sign_of_i2=if i<0 then -1 else if i==0 then 0 else 1;

]

3.6.6 Member Access Operator

It is possible to access members of a class instance using dot notation, i.e., the . operator.

[Example: R1.R for accessing the resistance component R of resistor R1. Another use of dot notation: local classes which are members of a class can of course also be accessed using dot notation on the name of the class, not on instances of the class.]

3.6.7 Built-in Variable time

All declared variables are functions of the independent variable time. The variable time is a built-in variable available in all models and blocks, which is treated as an input variable. It is implicitly defined as:

input Real time (final quantity = "Time",
                 final unit = "s");

The value of the start attribute of time is set to the time instant at which the simulation is started.

[Example:

encapsulated model SineSource
  import Modelica.Math.sin;
  connector OutPort=output Real;
  OutPort y=sin(time); // Uses the built-in variable time.
end SineSource;

]

3.7 Built-in Intrinsic Operators with Function Syntax

Certain built-in operators of Modelica have the same syntax as a function call. However, they do not behave as a mathematical function, because the result depends not only on the input arguments but also on the status of the simulation.

There are also built-in functions that depend only on the input argument, but also may trigger events in addition to returning a value. Intrinsic means that they are defined at the Modelica language level, not in the Modelica library. The following built-in intrinsic operators/functions are available:

  • Mathematical functions and conversion functions, see section 3.7.1 below.

  • Derivative and special purpose operators with function syntax, see section 3.7.4 below.

  • Event-related operators with function syntax, see section 3.7.5 below.

  • Array operators/functions, see section 10.1.1.

Note that when the specification references a function having the name of a built-in function it references the built-in function, not a user-defined function having the same name, see also section 12.5. With exception of the built-in String operator, all operators in this section can only be called with positional arguments.

3.7.1 Numeric Functions and Conversion Functions

The mathematical functions and conversion operators are listed below do not generate events.

Expression Description Details
abs(v) Absolute value (event-free) Function 3.1
sign(v) Sign of argument (event-free) Function 3.2
sqrt(v) Square root Function 3.3
Integer(e) Conversion from enumeration to Integer Operator 3.1
EnumTypeName(i) Conversion from Integer to enumeration Operator 3.2
String() Conversion to String Operator 3.3

All of these except for the String conversion operator are vectorizable according to section 12.4.6.

Additional non-event generating mathematical functions are described in section 3.7.3, whereas the event-triggering mathematical functions are described in section 3.7.2.

Function 3.1 abs
abs(v)
  • Expands into noEvent(if v >= 0 then v else -v). Argument v needs to be an Integer or Real expression.

Function 3.2 sign
sign(v)
  • Expands into noEvent(if v > 0 then 1 else if v < 0 then -1 else 0). Argument v needs to be an Integer or Real expression.

Function 3.3 sqrt
sqrt(v)
  • Square root of v if v0, otherwise an error occurs. Argument v needs to be an Integer or Real expression.

Operator 3.1 Integer
Integer(e)
  • Ordinal number of the expression e of enumeration type that evaluates to the enumeration value E.enumvalue, where Integer(E.e1) = 1, Integer(E.en) = n, for an enumeration type E = enumeration(e1, ..., en). See also section 4.8.5.2.

Operator 3.2 <EnumTypeName>
EnumTypeName(i)
  • For any enumeration type EnumTypeName, returns the enumeration value EnumTypeName.e such that 𝙸𝚗𝚝𝚎𝚐𝚎𝚛(𝙴𝚗𝚞𝚖𝚃𝚢𝚙𝚎𝙽𝚊𝚖𝚎.𝚎)=i. Refer to the definition of Integer above.

    It is an error to attempt to convert values of i that do not correspond to values of the enumeration type. See also section 4.8.5.3.

Operator 3.3 String
String(b, <options>)
String(i, <options>)
String(r, significantDigits=d, <options>)
String(r, format=s)
String(e, <options>)
  • Convert a scalar non-String expression to a String representation. The first argument may be a Boolean b, an Integer i, a Real r or an enumeration value e (section 4.8.5.2). The other arguments must use named arguments. For Real expressions the output shall be according to the Modelica grammar.

    The optional <options> are:

    • Integer minimumLength = 0: Minimum length of the resulting string. If necessary, the blank character is used to fill up unused space.

    • Boolean leftJustified = true: If true, the converted result is left justified in the string; if false it is right justified in the string.

    • Integer significantDigits = 6: Number of significant digits in the result string.

    [Examples of Real values formatted with 6 significant digits: 12.3456, 0.0123456, 12345600, 1.23456E-10.]

    The format string corresponding to <options> is:

    • For Real:
      (if leftJustified then "-" else "") + String(minimumLength)
        + "." + String(signficantDigits) + "g"

    • For Integer:
      (if leftJustified then "-" else "") + String(minimumLength) + "d"

    Form of the format string: According to ANSI-C the format string specifies one conversion specifier (excluding the leading %), shall not contain length modifiers, and shall not use ‘*’ for width and/or precision. For all numeric values the format specifiers ‘f’, ‘e’, ‘E’, ‘g’, ‘G’ are allowed. For integral values it is also allowed to use the ‘d’, ‘i’, ‘o’, ‘x’, ‘X’, ‘u’, and ‘c’ format specifiers (for non-integral values a tool may round, truncate or use a different format if the integer conversion characters are used).

    The ‘x’/‘X’ formats (hexa-decimal) and c (character) for Integer values give results that do not agree with the Modelica grammar.

3.7.2 Event Triggering Mathematical Functions

The operators listed below trigger events if used outside of a when-clause and outside of a clocked discrete-time partition (see section 16.8.1).

Expression Description Details
div(x, y) Division with truncation toward zero Operator 3.4
mod(x, y) Integer modulus Operator 3.5
rem(x, y) Integer remainder Operator 3.6
ceil(x) Smallest integer Real not less than x Operator 3.7
floor(x) Largest integer Real not greater than x Operator 3.8
integer(x) Largest Integer not greater than x Operator 3.9

These expression for div, ceil, floor, and integer are event generating expression. The event generating expression for mod(x,y) is floor(x/y), and for rem(x,y) it is div(x,y) – i.e. events are not generated when mod or rem changes continuously in an interval, but when they change discontinuously from one interval to the next.

[If this is not desired, the noEvent operator can be applied to them. E.g. noEvent(integer(v)).]

Operator 3.4 div
div(x, y)
  • Algebraic quotient x/y with any fractional part discarded (also known as truncation toward zero).

    [This is defined for / in C99; in C89 the result for negative numbers is implementation-defined, so the standard function div must be used.]

    Result and arguments shall have type Real or Integer. If either of the arguments is Real the result is Real otherwise Integer.

Operator 3.5 mod
mod(x, y)
  • Integer modulus of x/y, i.e. mod(x, y) = x - floor(x / y) * y. Result and arguments shall have type Real or Integer. If either of the arguments is Real the result is Real otherwise Integer.

    [Note, outside of a when-clause state events are triggered when the return value changes discontinuously. Examples: mod(3, 1.4) = 0.2, mod(-3, 1.4) = 1.2, mod(3, -1.4) = -1.2.]

Operator 3.6 rem
rem(x, y)
  • Integer remainder of x/y, such that div(x, y) * y + rem(x, y) = x. Result and arguments shall have type Real or Integer. If either of the arguments is Real the result is Real otherwise Integer.

    [Note, outside of a when-clause state events are triggered when the return value changes discontinuously. Examples: rem(3, 1.4) = 0.2, rem(-3, 1.4) = -0.2.]

Operator 3.7 ceil
ceil(x)
  • Smallest integer not less than x. Result and argument shall have type Real.

    [Note, outside of a when-clause state events are triggered when the return value changes discontinuously.]

Operator 3.8 floor
floor(x)
  • Largest integer not greater than x. Result and argument shall have type Real.

    [Note, outside of a when-clause state events are triggered when the return value changes discontinuously.]

Operator 3.9 integer
integer(x)
  • Largest integer not greater than x. The argument shall have type Real. The result has type Integer.

    [Note, outside of a when-clause state events are triggered when the return value changes discontinuously.]

3.7.3 Elementary Mathematical Functions

The functions listed below are elementary mathematical functions. Tools are expected to utilize well known properties of these functions (derivatives, inverses, etc) for symbolic processing of expressions and equations.

Expression Description Details
sin(x) Sine
cos(x) Cosine
tan(x) Tangent (x shall not be: , -π/2, π/2, 3π/2, )
asin(x) Inverse sine (-1x1)
acos(x) Inverse cosine (-1x1)
atan(x) Inverse tangent
atan2(y, x) Principal value of the arc tangent of y/x Function 3.4
sinh(x) Hyperbolic sine
cosh(x) Hyperbolic cosine
tanh(x) Hyperbolic tangent
exp(x) Exponential, base e
log(x) Natural (base e) logarithm (x>0)
log10(x) Base 10 logarithm (x>0)

These functions are the only ones that can also be called using the deprecated "builtin" external language, see section 12.9.

[End user oriented information about the elementary mathematical functions can be found for the corresponding functions in the Modelica.Math package.]

Function 3.4 atan2
atan2(y, x)
  • Principal value of the arc tangent of y/x, using the signs of the two arguments to determine the quadrant of the result. The result φ is in the interval [-π,π] and satisfies:

    |(x,y)|cos(φ) =x
    |(x,y)|sin(φ) =y

3.7.4 Derivative and Special Purpose Operators with Function Syntax

The operators listed below include the derivative operator and special purpose operators with function syntax.

Expression Description Details
der(𝑒𝑥𝑝𝑟) Time derivative Operator 3.10
delay(𝑒𝑥𝑝𝑟, ) Time delay Operator 3.11
cardinality(c) Number of occurrences in connect-equations Operator 3.12
homotopy(𝑎𝑐𝑡𝑢𝑎𝑙, 𝑠𝑖𝑚𝑝𝑙𝑖𝑓𝑖𝑒𝑑) Homotpy initialization Operator 3.13
semiLinear(x, k+, k-) Sign-dependent slope Operator 3.14
inStream(v) Stream variable flow into component Operator 3.15
actualStream(v) Actual value of stream variable Operator 3.16
spatialDistribution() Variable-speed transport Operator 3.17
getInstanceName() Name of instance at call site Operator 3.18

The special purpose operators with function syntax where the call below uses named arguments can be called with named arguments (with the specified names), or with positional arguments (the inputs of the functions are in the order given in the calls below).

Operator 3.10 der
der(𝑒𝑥𝑝𝑟)
  • The time derivative of 𝑒𝑥𝑝𝑟. If the expression 𝑒𝑥𝑝𝑟 is a scalar it needs to be a subtype of Real. The expression and all its time-varying subexpressions must be continuous and semi-differentiable. If 𝑒𝑥𝑝𝑟 is an array, the operator is applied to all elements of the array. For non-scalar arguments the function is vectorized according to section 10.6.12.

    [For Real parameters and constants the result is a zero scalar or array of the same size as the variable.]

Operator 3.11 delay
delay(𝑒𝑥𝑝𝑟, 𝑑𝑒𝑙𝑎𝑦𝑇𝑖𝑚𝑒, 𝑑𝑒𝑙𝑎𝑦𝑀𝑎𝑥)
delay(𝑒𝑥𝑝𝑟, 𝑑𝑒𝑙𝑎𝑦𝑇𝑖𝑚𝑒)
  • Evaluates to 𝑒𝑥𝑝𝑟(time - 𝑑𝑒𝑙𝑎𝑦𝑇𝑖𝑚𝑒) for 𝚝𝚒𝚖𝚎>𝚝𝚒𝚖𝚎.𝚜𝚝𝚊𝚛𝚝+𝑑𝑒𝑙𝑎𝑦𝑇𝑖𝑚𝑒 and 𝑒𝑥𝑝𝑟(time.start) for 𝚝𝚒𝚖𝚎𝚝𝚒𝚖𝚎.𝚜𝚝𝚊𝚛𝚝+𝑑𝑒𝑙𝑎𝑦𝑇𝑖𝑚𝑒. The arguments, i.e., 𝑒𝑥𝑝𝑟, 𝑑𝑒𝑙𝑎𝑦𝑇𝑖𝑚𝑒 and 𝑑𝑒𝑙𝑎𝑦𝑀𝑎𝑥, need to be subtypes of Real. 𝑑𝑒𝑙𝑎𝑦𝑀𝑎𝑥 needs to be additionally a parameter expression. The following relation shall hold: 0𝑑𝑒𝑙𝑎𝑦𝑇𝑖𝑚𝑒𝑑𝑒𝑙𝑎𝑦𝑀𝑎𝑥, otherwise an error occurs. If 𝑑𝑒𝑙𝑎𝑦𝑀𝑎𝑥 is not supplied in the argument list, 𝑑𝑒𝑙𝑎𝑦𝑇𝑖𝑚𝑒 needs to be a parameter expression. For non-scalar arguments the function is vectorized according to section 10.6.12. For further details, see section 3.7.4.1.

Operator 3.12 cardinality
cardinality(c)
  • [This is a deprecated operator. It should no longer be used, since it will be removed in one of the next Modelica releases.]

    Returns the number of (inside and outside) occurrences of connector instance c in a connect-equation as an Integer number. For further details, see section 3.7.4.3.

Operator 3.13 homotopy
homotopy(actual=𝑎𝑐𝑡𝑢𝑎𝑙, simplified=𝑠𝑖𝑚𝑝𝑙𝑖𝑓𝑖𝑒𝑑)
  • The scalar expressions 𝑎𝑐𝑡𝑢𝑎𝑙 and 𝑠𝑖𝑚𝑝𝑙𝑖𝑓𝑖𝑒𝑑 are subtypes of Real. A Modelica translator should map this operator into either of the two forms:

    1. 1.

      Returns 𝑎𝑐𝑡𝑢𝑎𝑙 (trivial implementation).

    2. 2.

      In order to solve algebraic systems of equations, the operator might during the solution process return a combination of the two arguments, ending at actual.

      [Example: 𝑎𝑐𝑡𝑢𝑎𝑙λ+𝑠𝑖𝑚𝑝𝑙𝑖𝑓𝑖𝑒𝑑(1-λ), where λ is a homotopy parameter going from 0 to 1.]

      The solution must fulfill the equations for homotopy returning 𝑎𝑐𝑡𝑢𝑎𝑙.

    For non-scalar arguments the function is vectorized according to section 12.4.6. For further details, see section 3.7.4.4.

Operator 3.14 semiLinear
semiLinear(x, k+, k-)
  • Returns: smooth(0, if x >= 0 then k+ * x else k- * x). The result is of type Real. For non-scalar arguments the function is vectorized according to section 10.6.12. For further details, see section 3.7.4.5 (especially in the case when x=0).

Operator 3.15 inStream
inStream(v)
  • inStream(v) is only allowed for stream variables v defined in stream connectors, and is the value of the stream variable v close to the connection point assuming that the flow is from the connection point into the component. This value is computed from the stream connection equations of the flow variables and of the stream variables. The operator is vectorizable. For further details, see section 15.2.

Operator 3.16 actualStream
actualStream(v)
  • actualStream(v) returns the actual value of the stream variable v for any flow direction. The operator is vectorizable. For further details, see section 15.3.

Operator 3.17 spatialDistribution
spatialDistribution(
  in0=in0, in1=in1, x=x,
  positiveVelocity=,
  initialPoints=,
  initialValues=)
  • spatialDistribution allows approximation of variable-speed transport of properties. For further details, see section 3.7.4.2.

Operator 3.18 getInstanceName
getInstanceName()
  • Returns a string with the name of the model/block that is simulated, appended with the fully qualified name of the instance in which this function is called. For further details, see section 3.7.4.6.

A few of these operators are described in more detail in the following.

3.7.4.1 delay

[delay allows a numerical sound implementation by interpolating in the (internal) integrator polynomials, as well as a more simple realization by interpolating linearly in a buffer containing past values of expression expr. Without further information, the complete time history of the delayed signals needs to be stored, because the delay time may change during simulation. To avoid excessive storage requirements and to enhance efficiency, the maximum allowed delay time has to be given via 𝑑𝑒𝑙𝑎𝑦𝑀𝑎𝑥.

This gives an upper bound on the values of the delayed signals which have to be stored. For real-time simulation where fixed step size integrators are used, this information is sufficient to allocate the necessary storage for the internal buffer before the simulation starts. For variable step size integrators, the buffer size is dynamic during integration. In principle, delay could break algebraic loops. For simplicity, this is not supported because the minimum delay time has to be give as additional argument to be fixed at compile time. Furthermore, the maximum step size of the integrator is limited by this minimum delay time in order to avoid extrapolation in the delay buffer.]

3.7.4.2 spatialDistribution

[Many applications involve the modelling of variable-speed transport of properties. One option to model this infinite-dimensional system is to approximate it by an ODE, but this requires a large number of state variables and might introduce either numerical diffusion or numerical oscillations. Another option is to use a built-in operator that keeps track of the spatial distribution of z(x,t), by suitable sampling, interpolation, and shifting of the stored distribution. In this case, the internal state of the operator is hidden from the ODE solver.]

spatialDistribution allows the infinite-dimensional problem below to be solved efficiently with good accuracy

z(y,t)t+v(t)z(y,t)y =0.0
z(0.0,t) =in0(t) if v0
z(1.0,t) =in1(t) if v<0

where z(y,t) is the transported quantity, y is the normalized spatial coordinate (0.0y1.0), t is the time, v(t)=der(x) is the normalized transport velocity and the boundary conditions are set at either y=0.0 or y=1.0, depending on the sign of the velocity. The calling syntax is:

(out0, out1) = spatialDistribution(in0, in1, x, positiveVelocity,
                                   initialPoints = {0.0, 1.0},
                                   initialValues = {0.0, 0.0});

where in0, in1, out0, out1, x, v are all subtypes of Real, positiveVelocity is a Boolean, initialPoints and initialValues are arrays of subtypes of Real of equal size, containing the y coordinates and the z values of a finite set of points describing the initial distribution of z(y,t0). The out0 and out1 are given by the solutions at z(0.0,t) and z(1.0,t); and in0 and in1 are the boundary conditions at z(0.0,t) and z(1.0,t) (at each point in time only one of in0 and in1 is used). Elements in the initialPoints array must be sorted in non-descending order. The operator can not be vectorized according to the vectorization rules described in section 12.4.6. The operator can be vectorized only with respect to the arguments in0 and in1 (which must have the same size), returning vectorized outputs out0 and out1 of the same size; the arguments initialPoints and initialValues are vectorized accordingly.

The solution, z, can be described in terms of characteristics:

z(y+tt+βv(α)dα,t+β)=z(y,t),for all β as long as staying inside the domain

This allows the direct computation of the solution based on interpolating the boundary conditions.

spatialDistribution can be described in terms of the pseudo-code given as a block:

block spatialDistribution
  input Real in0;
  input Real in1;
  input Real x;
  input Boolean positiveVelocity;
  parameter Real initialPoints(each min=0, each max=1)[:] = {0.0, 1.0};
  parameter Real initialValues[:] = {0.0, 0.0};
  output Real out0;
  output Real out1;
protected
  Real points[:];
  Real values[:];
  Real x0;
  Integer m;
algorithm
  /* The notation
   *   x <and then> y
   * is used below as a shorthand for
   *   if x then y else false
   * also known as ”short-circuit evaluation of x and y”.
   */
  if positiveVelocity then
    out1 := interpolate(points, values, 1 - (x - x0));
    out0 := values[1]; // Similar to in0 but avoiding algebraic loop.
  else
    out0 := interpolate(points, values, 0 - (x - x0));
    out1 := values[end]; // Similar to in1 but avoiding algebraic loop.
  end if;
  when <acceptedStep> then
    if x > x0 then
      m := size(points, 1);
      while m > 0 <and then> points[m] + (x - x0) >= 1 loop
        m := m - 1;
      end while;
      values := cat(1,
                    {in0},
                    values[1:m],
                    {interpolate(points, values, 1 - (x - x0))});
      points := cat(1, {0}, points[1:m] .+ (x-x0), {1});
    elseif x < x0 then
      m := 1;
      while m < size(points, 1) <and then> points[m] + (x - x0) <= 0 loop
        m := m + 1;
      end while;
      values := cat(1,
                    {interpolate(points, values, 0 - (x - x0))},
                    values[m:end],
                    {in1});
      points := cat(1, {0}, points[m:end] .+ (x - x0), {1});
    end if;
    x0 := x;
  end when;
initial algorithm
  x0 := x;
  points := initialPoints;
  values := initialValues;
end spatialDistribution;

[Note that the implementation has an internal state and thus cannot be described as a function in Modelica; initialPoints and initialValues are declared as parameters to indicate that they are only used during initialization.

The infinite-dimensional problem stated above can then be formulated in the following way:

der(x) = v;
(out0, out1) = spatialDistribution(in0, in1, x, v >= 0,
                                   initialPoints, initialValues);

Events are generated at the exact instants when the velocity changes sign – if this is not needed, noEvent can be used to suppress event generation.

If the velocity is known to be always positive, then out0 can be omitted, e.g.:

der(x) = v;
(, out1) = spatialDistribution(in0, 0, x, true, initialPoints, initialValues);

Technically relevant use cases for the use of spatialDistribution are modeling of electrical transmission lines, pipelines and pipeline networks for gas, water and district heating, sprinkler systems, impulse propagation in elongated bodies, conveyor belts, and hydraulic systems. Vectorization is needed for pipelines where more than one quantity is transported with velocity v in the example above.]

3.7.4.3 cardinality (deprecated)

[cardinality is deprecated for the following reasons and will be removed in a future release:

  • Reflective operator may make early type checking more difficult.

  • Almost always abused in strange ways

  • Not used for Bond graphs even though it was originally introduced for that purpose.

]

[cardinality allows the definition of connection dependent equations in a model, for example:

connector Pin
  Real v;
  flow Real i;
end Pin;
model Resistor
  Pin p, n;
equation
  assert(cardinality(p) > 0 and cardinality(n) > 0,
         "Connectors p and n of Resistor must be connected");
  // Equations of resistor
  ...
end Resistor;

]

The cardinality is counted after removing conditional components, and shall not be applied to expandable connectors, elements in expandable connectors, or to arrays of connectors (but can be applied to the scalar elements of array of connectors). cardinality should only be used in the condition of assert and if-statements that do not contain connect and similar operators, see section 16.8.1).

3.7.4.4 homotopy

[During the initialization phase of a dynamic simulation problem, it often happens that large nonlinear systems of equations must be solved by means of an iterative solver. The convergence of such solvers critically depends on the choice of initial guesses for the unknown variables. The process can be made more robust by providing an alternative, simplified version of the model, such that convergence is possible even without accurate initial guess values, and then by continuously transforming the simplified model into the actual model. This transformation can be formulated using expressions of this kind:

λ𝚊𝚌𝚝𝚞𝚊𝚕+(1-λ)𝚜𝚒𝚖𝚙𝚕𝚒𝚏𝚒𝚎𝚍

in the formulation of the system equations, and is usually called a homotopy transformation. If the simplified expression is chosen carefully, the solution of the problem changes continuously with λ, so by taking small enough steps it is possible to eventually obtain the solution of the actual problem.

The operator can be called with ordered arguments or preferably with named arguments for improved readability.

It is recommended to perform (conceptually) one homotopy iteration over the whole model, and not several homotopy iterations over the respective non-linear algebraic equation systems. The reason is that the following structure can be present:

w = f1(x) // has homotopy
0 = f2(der(x), x, z, w)

Here, a non-linear equation system f2 is present. homotopy is, however used on a variable that is an “input” to the non-linear algebraic equation system, and modifies the characteristics of the non-linear algebraic equation system. The only useful way is to perform the homotopy iteration over f1 and f2 together.

The suggested approach is “conceptual”, because more efficient implementations are possible, e.g. by determining the smallest iteration loop, that contains the equations of the first BLT block in which homotopy is present and all equations up to the last BLT block that describes a non-linear algebraic equation system.

A trivial implementation of homotopy is obtained by defining the following function in the global scope:

function homotopy
  input Real actual;
  input Real simplified;
  output Real y;
algorithm
  y := actual;
  annotation(Inline = true);
end homotopy;

]

[Example 1: In electrical systems it is often difficult to solve non-linear algebraic equations if switches are part of the algebraic loop. An idealized diode model might be implemented in the following way, by starting with a “flat” diode characteristic and then move with homotopy to the desired “steep” characteristic:

model IdealDiode
  ...
  parameter Real Goff = 1e-5;
protected
  Real Goff_flat = max(0.01, Goff);
  Real Goff2;
equation
  off = s < 0;
  Goff2 = homotopy(actual=Goff, simplified=Goff_flat);
  u = s*(if off then 1 else Ron2) + Vknee;
  i = s*(if off then Goff2 else 1 ) + Goff2*Vknee;
  ...
end IdealDiode;

]

[Example 2: In electrical systems it is often useful that all voltage sources start with zero voltage and all current sources with zero current, since steady state initialization with zero sources can be easily obtained. A typical voltage source would then be defined as:

model ConstantVoltageSource
  extends Modelica.Electrical.Analog.Interfaces.OnePort;
  parameter Modelica.Units.SI.Voltage V;
equation
  v = homotopy(actual=V, simplified=0.0);
end ConstantVoltageSource;

]

[Example 3: In fluid system modelling, the pressure/flowrate relationships are highly nonlinear due to the quadratic terms and due to the dependency on fluid properties. A simplified linear model, tuned on the nominal operating point, can be used to make the overall model less nonlinear and thus easier to solve without accurate start values. Named arguments are used here in order to further improve the readability.

model PressureLoss
  import Modelica.Units.SI;
  ...
  parameter SI.MassFlowRate m_flow_nominal "Nominal mass flow rate";
  parameter SI.Pressure dp_nominal "Nominal pressure drop";
  SI.Density rho "Upstream density";
  SI.DynamicViscosity lambda "Upstream viscosity";
equation
  ...
  m_flow = homotopy(actual = turbulentFlow_dp(dp, rho, lambda),
  simplified = dp/dp_nominal*m_flow_nominal);
  ...
end PressureLoss;

]

[Example 4: Note that homotopy shall not be used to combine unrelated expressions, since this can generate singular systems from combining two well-defined systems.

model DoNotUse
  Real x;
  parameter Real x0 = 0;
equation
  der(x) = 1-x;
initial equation
  0 = homotopy(der(x), x - x0);
end DoNotUse;

The initial equation is expanded into

0=λ*der(x)+(1-λ)(x-x0)

and you can solve the two equations to give

x=λ+(λ-1)x02λ-1

which has the correct value of x0 at λ=0 and of 1 at λ=1, but unfortunately has a singularity at λ=0.5.]

3.7.4.5 semiLinear

(See definition of semiLinear in section 3.7.4). In some situations, equations with semiLinear become underdetermined if the first argument (x) becomes zero, i.e., there are an infinite number of solutions. It is recommended that the following rules are used to transform the equations during the translation phase in order to select one meaningful solution in such cases:

  • The equations

    y = semiLinear(x, sa, s1);
    y = semiLinear(x, s1, s2);
    y = semiLinear(x, s2, s3);
    ...
    y = semiLinear(x, sN, sb);
    ...

    may be replaced by

    s1 = if x >= 0 then sa else sb
    s2 = s1;
    s3 = s2;
    ...
    sN=sN-1;
    y = semiLinear(x, sa, sb);
  • The equations

    x = 0;
    y = 0;
    y = semiLinear(x, sa, sb);

    may be replaced by

    x = 0
    y = 0;
    sa = sb;

[For symbolic transformations, the following property is useful (this follows from the definition):

semiLinear(m_flow, port_h, h);

is identical to:

-semiLinear(-m_flow, h, port_h);

The semiLinear function is designed to handle reversing flow in fluid systems, such as

H_flow = semiLinear(m_flow, port.h, h);

i.e., the enthalpy flow rate H_flow is computed from the mass flow rate m_flow and the upstream specific enthalpy depending on the flow direction.]

3.7.4.6 getInstanceName

Returns a string with the name of the model/block that is simulated, appended with the fully qualified name of the instance in which this function is called.

[Example:

package MyLib
  model Vehicle
    Engine engine;
    ...
  end Vehicle;
  model Engine
    Controller controller;
    ...
  end Engine;
  model Controller
  equation
    Modelica.Utilities.Streams.print("Info from: " + getInstanceName());
  end Controller;
end MyLib;

If MyLib.Vehicle is simulated, the call of getInstanceName() returns "Vehicle.engine.controller".]

If this function is not called inside a model or block (e.g. the function is called in a function or in a constant of a package), the return value is not specified.

[The simulation result should not depend on the return value of this function.]

3.8 Variability of Expressions

The concept of variability of an expression indicates to what extent the expression can vary over time. See also section 4.4.4 regarding the concept of variability. There are four levels of variability of expressions, starting from the least variable:

  • constant variability

  • parameter variability

  • discrete-time variability

  • continuous-time variability

While many invalid models can be rejected based on the declared variabilities of variables alone (without the concept of expression variability), the following rules both help enforcing compliance of computed solutions to declared variability, and impose additional restrictions that simplify reasoning and reporting of errors:

  • For an assignment v := expr or binding equation v = expr, v must be declared to be at least as variable as expr.

  • When determining whether an equation can contribute to solving for a variable v (for instance, when applying the perfect matching rule, see section 8.4), the equation can only be considered contributing if the resulting solution would be at most as variable as v.

  • The right-hand side expression in a binding equation (that is, expr) of a parameter component and of the base type attributes (such as start) needs to be a parameter or constant expression.

  • If v is a discrete-time component then expr needs to be a discrete-time expression.

3.8.1 Constant Expressions

Constant expressions are:

  • Real, Integer, Boolean, String, and enumeration literals.

  • Variables declared as constant.

  • Except for the special built-in operators initial, terminal, der, edge, change, sample, and pre, a function or operator with constant subexpressions as argument (and no parameters defined in the function) is a constant expression.

  • Some function calls are constant expressions regardless of the arguments:

    • ndims(A)

Components declared as constant shall have an associated declaration equation with a constant expression, if the constant is directly in the simulation model, or used in the simulation model. The value of a constant can be modified after it has been given a value, unless the constant is declared final or modified with a final modifier. A constant without an associated declaration equation can be given one by using a modifier.

3.8.2 Parameter Expressions

Parameter expressions are:

  • Constant expressions.

  • Variables declared as parameter.

  • Input variables in functions behave as though they were parameter expressions.

  • Except for the special built-in operators initial, terminal, der, edge, change, sample, and pre, a function or operator with parameter subexpressions is a parameter expression.

  • Some function calls are parameter expressions even if the arguments are not:

    • cardinality(c), see restrictions for use in section 3.7.4.3.

    • end in A[ end ] if A is variable declared in a non-function class.

    • size(A) (including size(A, j) where j is parameter expression) if A is variable declared in a non-function class.

    • Connections.isRoot(A.R)

    • Connections.rooted(A.R)

3.8.3 Discrete-Time Expressions

Discrete-time expressions are:

  • Parameter expressions.

  • Discrete-time variables, i.e., Integer, Boolean, String variables and enumeration variables, as well as Real variables assigned in when-clauses.

  • Function calls where all input arguments of the function are discrete-time expressions.

  • Expressions where all the subexpressions are discrete-time expressions.

  • Expressions in the body of a when-clause, initial equation, or initial algorithm.

  • Unless inside noEvent: Ordered relations (>, <, >=, <=) and the event generating functions ceil, floor, div, and integer, if at least one argument is non-discrete time expression and subtype of Real.

    [These will generate events, see section 8.5. Note that rem and mod generate events but are not discrete-time expressions. In other words, relations inside noEvent, such as noEvent(x>1), are not discrete-time expressions.]

  • The functions pre, edge, and change result in discrete-time expressions.

  • Expressions in functions behave as though they were discrete-time expressions.

For an equation expr1 = expr2 where neither expression is of base type Real, both expressions must be discrete-time expressions. For record equations the equation is split into basic types before applying this test.

[This restriction guarantees that noEvent cannot be applied to Boolean, Integer, String, or enumeration equations outside of a when-clause, because then one of the two expressions is not discrete-time.]

Inside an if-expression, if-clause, while-statement or for-clause, that is controlled by a non-discrete-time (that is continuous-time, but not discrete-time) switching expression and not in the body of a when-clause, it is not legal to have assignments to discrete-time variables, equations between discrete-time expressions, or real elementary relations/functions that should generate events.

[The restriction above is necessary in order to guarantee that all equations for discrete-time variable are discrete-time expressions, and to ensure that crossing functions do not become active between events.]

[Example: The (underdetermined) model Test below illustrates two kinds of consequences due to variability constraints. First, it contains variability errors for declaration equations and assignments. Second, it illustrates the impact of variability on the matching of equations to variables, which can lead to violation of the perfect matching rule.

model Constants
  parameter Real p1 = 1;
  constant Real c1 = p1 + 2; // error, not a constant expression
  parameter Real p2 = p1 + 2; // fine
end Constants;
model Test
  Constants c1(p1=3); // fine
  Constants c2(p2=7); // fine, declaration equation can be modified
  Real x;
  Boolean b1 = noEvent(x > 1); // error, since b1 is a discrete-time variable
                               // and noEvent(x > 1) is not discrete-time.
  Boolean b2;
  Integer i1;
  Integer i2;
algorithm
  i1 := x; // error, assignment to variable of lesser variability.
equation
  b2 = noEvent(x > 1); // no variability error, but equation cannot be matched.
  i2 = x;              // no variability error, and can be matched to x.
end Test;

]

3.8.4 Continuous-Time Expressions

All expressions are continuous-time expressions including constant, parameter and discrete expressions. The term non-discrete-time expression refers to expressions that are neither constant, parameter nor discrete-time expressions.